# Maintainer: Joshua Harris <sheowder@mailfence.com>

# This PKGBUILD is generated using a template. Some fields are filled in from
# ant variables. Please email concerns about the template to Joshua Harris,
# else email the other maintainers if a mirror PKGBUILD contains errors with
# manually replaced ant fields.

pkgname=sheowder
pkgver=1.0.0
pkgrel=1
pkgdesc="Fight with mage and explore Sheowder!"
arch=("any")
url=https://www.sheowder.net
license=("mit")
depends=("java-runtime>=25")
makedepends=("gendesk" "unzip")
optdepends=("pulseaudio-alsa: stable audio playback")
sheowder_ver="sheowder-${pkgver}"
source=("${sheowder_ver}.jar::https://sheowder.net/downloads/Sheowder.jar")
noextract=("${sheowder_ver}.jar")
sha256sums=("8f2a3a80838744d5a4d8fdb02776857b407118407ff39f0a6a567d489a29915b")

build() {

    unzip -j "${sheowder_ver}.jar" "core/game_icon.png"

    gendesk -f -n \
        --name "Sheowder" \
        --pkgname "${sheowder_ver}" \
        --pkgdesc "${pkgdesc}" \
        --exec="/usr/bin/sheowder" \
        --icon="/usr/share/icons/hicolor/256x256/apps/sheowder.png" \
        --categories="Game;StrategyGame;"

    echo -e "#!/bin/sh\njava -Dsun.java2d.opengl=True -Xmx120m -jar /usr/share/java/${sheowder_ver}.jar" > launcher
}

package() {

    install -Dm644 "${sheowder_ver}.jar" "${pkgdir}/usr/share/java/${sheowder_ver}.jar"
    install -Dm755 "launcher" "${pkgdir}/usr/bin/sheowder"

    install -Dm644 "game_icon.png" "${pkgdir}/usr/share/icons/hicolor/256x256/apps/sheowder.png"
    install -Dm644 "${sheowder_ver}.desktop" "${pkgdir}/usr/share/applications/sheowder.desktop"

}